AN984
使用 dsPIC30F MCU 控制交流感应电机
作者:
Steve Bowling
Microchip Technology
引言
此应用笔记说明了如何使用 dsPIC30F MCU 来控制交流
感应电机 (AC Induction Motor , ACIM )。本文中的讨
论基于 dsPICDEM™ MC 电机控制开发系统,但是您仍
可选择使用自己的硬件。 dsPICDEM MC 电机控制开发
系统带有电气隔离设备并且具有故障保护功能。有了这
些功能,就可以安全地开发电机控制应用程序并避免软
件错误对硬件造成损害。
此应用笔记中提供的代码是一个简单的示例,它实现了
对 ACIM 的基本变速控制。有助于您学习 dsPIC30F 架
构和 ACIM 控制的基础知识。
推荐使用的硬件
此应用笔记中给出的代码可以在下列 Microchip 设备上
运行:
®
• MPLAB
(部件号: DV164005)
• dsPICDEM MC1 电机控制开发板
(部件号: DM300020)
• dsPICDEM MC1H 3 相高压电源模块
(部件号: DM300021)
• 3 相 ACIM 高压电机 (208/460V)
(部件号:AC300021 )
如果您喜欢,也可使用自己的 3 相或单相 ACIM 。推荐
的功率范围为 1/6 到 1/2 HP 。
ICD 2 在线调试器和器件编程器
背景知识
变速 ACIM 驱动从工业控制应用演变而来。过去更偏向
于使用绕组式直流电机,因为它们更易于控制。只要简
单地改变电机电流就可以调节转矩输出和电机速度。然
而,这些直流电机确实存在一些缺点。在工业应用中使
用的直流电机需要定期检修,以替换磨损的电刷和转子
绕组。由于直流电机的转子绕组在机壳内部,所以它们
的散热十分困难。
ACIM 具有简单的转子构造并且不使用电刷。由于这些
原因, ACIM 比直流电机更耐久。唯一需要保养的机械
组件只有转子轴承。该转子就是一个由磁性叠片构成的
钢笼,因此耐热性要好得多。 ACIM 的耐久性使它成为
了一种极具吸引力的选择。
ACIM 的变速控制从概念上说非常简单。必须改变驱动
电压的频率和幅值以改变电机速度。早期的 ACIM 驱动
电路采用 SCR 器件,连接方式如图 1 所示。通过在适
当的时间开通每个 SCR ,可以在电机各相上产生非常近
似的正弦电压。由于有六种不同的方法可以使 SCR 器
件导通从而产生电机电流,这种类型的电路通常被称为
“六步”驱动电路。但是,六步驱动电路的高次谐波成
分会产生高热量,而且在低频时性能不佳。
从六步驱动时代至今,半导体技术已有了巨大的进步。
SCR 器件现在被 MOSFET 或 IGBT 器件取代,后面这
两种器件能以最小的功率损耗在相对较高的频率下导通
和关断。可以使用 PWM 信号控制这些器件以产生连续
变化的驱动电压和电流。
其他参考文档
以下应用笔记提供了有用的背景信息:
,“
• AN887
( DS00887)
• AN889
Motors Using PIC16F7X7 Microcontrollers
( DS00889)
• AN900 ,“Controlling 3-Phase AC Induction
Motors Using the PIC18F4431
• AN908
量控制》
2005 Microchip Technology Inc. DS00984A_CN 第 1 页
AC Induction Motor Fundamentals
,“
VF Control of 3-Phase Induction
”
(DS00900 )
,《使用
dsPIC30F
(DS00908A_CN )
实现交流感应电机的矢
”
”
AN984
图 1: SCR 逆变器电路
交流
电源
SCR X6
3 相
ACIM
+
单相 ACIM 与三相 ACIM 的比较
大多数工业用电机具有三相绕组。三相电源广泛用于工
业环境。民用环境通常只使用单相电源,这就为在民用
环境中使用 ACIM 带来了问题。
三相电机是用来进行变速控制的最佳选择。在所有运行
速度下,三相电机均能提供良好的转矩性能。也可使用
单相电机,但是它们在低速范围内性能受限。某些单相
感应电机在低速运行时,可能会有强烈的转矩脉动。
三相电机通以三相电源后,可以在定子绕组中产生真正
的旋转磁场。但是,如果不做一些修改,只带有单个定
子绕组的 ACIM 将无法产生旋转磁场。可用以下几种方
法解决该旋转磁场的问题。
罩极电机具有由层叠铁片构成的磁极结构。在该结构中
放置了一个线圈。通过在两个关键位置将短路环环绕在
磁极叠片上可以产生 “旋转”磁场。短路环使磁通分布
不均,从而产生旋转磁场。
解决旋转磁场问题的另一个方法是在定子上的不同位置
放置两个电绕组。这种类型的电机称为分相 ACIM 。在
大多数情况下,两个绕组中的一个绕组具有较低的电阻
抗,被指定为主绕组或“运转”绕组。另一个绕组具有
较高的阻抗,被指定为副绕组或 “起动”绕组。
通常,有三种类型的分相电机。第一种类型具有两个绕
组、一个离心式开关和一对输入端。这类电机通常用于
风扇和鼓风机。起动时,两个绕组并联。当电机接近全
速时,离心式开关会断开起动绕组。一旦电机以足够的
速度旋转之后,无需起动绕组就可运转。这类电机在起
动时效率不高,但是风扇或鼓风机在低速时通常也不会
带有很大负载。
第二种分相电机有两个绕组、一个离心式开关和一个与
起动绕组串联的电容。这个电容提供相移从而增大了起
动转矩并减小了起动电流。当电机接近全速后,离心式
开关断开起动绕组 (和电容) 。这类电机通常被称为
“电容起动”电机。
第三类分相电机省去了离心式开关,但是仍有一个电容
与副绕组串联。由于没有离心式开关,因此副绕组从不
会断开。这类分相电机通常被称为 “电容运转”电机,
在所有类型的分相电机中性能最佳。电容运转电机在运
行速度范围之内有最佳的转矩。在所有类型的单相
ACIM 中,电容运转电机是进行变速控制的最佳选择。
DS00984A_CN 第 2 页 2005 Microchip Technology Inc.
AN984
逆变电路
变速 ACIM 应用需要逆变电路来完成两个功能。首先,
输入的主交流电需要经过整形和滤波以产生直流母线电
压。其次,直流母线电压必须再转换为为电机供电的交
流电流。图 2 中的电路可用来控制三相电机。
您可能已注意到我说的是“交流电流”而不是“交流电
压”。我们将使用在 dsPIC
控制逆变器电路中的功率晶体管。如果将示波器探头放
在三相连接中的某相连接上,将会看到幅值大约与直流
母线电压相等的 PWM 信号。由于电机绕组是感性的,
输入电压将被积分产生与 PWM 占空比成比例的电机电
流。调制 PWM 占空比,即可产生任意波形的交流电流。
图 2 : 三相逆变器电路
交流主
供电电压
®
MCU 上电机控制 PWM 来
+
根据想要控制的 ACIM 的类型可以使用不同类型的逆变
器电路。无论使用何种类型的逆变器电路,都可以把直
流母线上的每对互补的晶体管视作受 PWM 发生器控制
的单个器件,如图 3 所示。每对互补的晶体管均连接到
电机的一相绕组。
像使用数模转换器那样,使用 PWM 发生器同样可以产
生任何所需波形的电机电流。50% 的 PWM 占空比一般
被用作零电流参考点。如果所有的 PWM 占空比都是
50% ,那么将对每相绕组施加同一个平均电压,电机中
流过的平均电流为零。如果 PWM 的占空比高于 50% ,
那么在绕组中将产生正电流。如果占空比低于 50% ,那
么在绕组中将产生负电流。
IGBT X6
3 相
ACIM
图 3: PWM 框图
PWM 发生器
dsPIC® PWM 外设
死区延迟
死区延迟
驱动器
驱动器
V
BUS(总线电压)
负载
2005 Microchip Technology Inc. DS00984A_CN 第 3 页
AN984
可供单相电机选用的逆变器电路
如果希望使用晶体管逆变器电路控制分相电机,有几种
不同的逆变器拓扑方案可供选择。如果希望省去电容而
用软件实现相移,可以使用上面介绍的三相逆变器电
路,如图 4 所示。使用逆变器驱动副绕组,可以在副绕
组上产生任意相移和幅值的电流。
图 4 :用3 相逆变器驱动分相电机
交流主
供电电压
图 5 :用H 桥逆变器驱动分相电机
+
分相电机也可以用 H 桥逆变器驱动,如图 5 所示。此
方案需要一个运转电容,但是省去了两个逆变器开关器
件。此电路的缺点在于电机的旋转方向是由电路中电容
的位置决定的。H 桥逆变器电路还可以用来驱动具有单
个绕组的罩极电机。
驱动分相电机或罩极电机的另一个方法是使用带 H 桥逆
变器的倍压电路,如图 6 所示。在此电路中,开关器件
上会有更高的直流母线电压。
副绕组
主绕组
公共端
交流主
供电电压
图 6 : 用倍压器电路驱动分相电机
交流主
供电电压
运转电容
+
+
+
主绕组
公共端
副绕组
主绕组
公共端
DS00984A_CN 第 4 页 2005 Microchip Technology Inc.
AN984
产生正弦波
产生正弦波形最简便的方法就是使用查找表。也可以花
费 CPU 时间来实时计算正弦值,但是这样做不划算,因
此通常会使用一个包含正弦波所有点的查找表。每经过
一个周期性的间隔从该表读出正弦值,将该值进行换算
使之符合所允许的占空比范围,然后将它写入占空比寄
存器。
软件中的正弦指针变量用于定义表中的当前位置。必须
以周期性的间隔 (通常在每个 PWM 周期的开头)调节
此指针。如果在每个间隔将固定的调节值加给该指针,
则该软件指针将以固定的频率在表中前移。查找表的长
度通常被设置为 2 的偶次幂,如 64 、128 或 256 。因 此
每次改变指针的值后均无需软件检查该值。该指针计满
返回并复位为 0 。
表中点的数量
这是在创建查找表时经常被问到的问题。对于此问题没
有明确的答案。表中的点太少将导致电机电流波形中的
“阶梯”效应。阶梯效应将引起电机电流失真,从而导
致更高的发热。而表中的点太多则会用尽 MCU 宝贵的
存储器空间。一个很好的经验方法是将 PWM 载波频率
除以所需的最大调制频率所得的值作为查找表中的点
数。通常选择刚超出音域的频率作为 PWM 载波频率。
假定为典型的 ACIM 选定了 16 kHz 的 PWM 载波信号,
并且最大调制频率为 60 Hz :
公式 1 :
表中值的个数 = f
PWM/fMODMAX
= 16,000/60
= 267
正弦表指针
选定了正弦表的大小之后,就可以选择正弦表指针变量
的大小了。假定使用了含有 256 个值的表来获取正弦
值。乍一看,可能觉得 8 位指针值已经足够了。然而,
您会希望指针值大一些以便产生很低的调制频率。
此应用笔记中的代码示例使用了16 位的正弦表指针。该
指针可表示完整的 360 度角度,其中 0x0000 表示0 度,
而 0xFFFF 表示 359.9 度。每次需要从查找表中获取新
值时,指针变量的高 8 位被用作指针索引,而低 8 位可
被视作小数位。
您可能想知道调制频率的分辨率。要确定此分辨率,需
要知道调节正弦表指针的频率。现在,假定每个 PWM
周期调节一次。假定 PWM 频率为 16 kHz ,调制频率分
辨率将是:
公式 2 :
调制频率分辨率 = f
= 0.244 Hz/ 位
因此,此角度分辨率和 PWM 载波频率允许每一步对调
制频率调节 0.244 Hz 。对于我们的变速应用,当调制频
率为 60 Hz 时电机全速运行。要确定提供 60 Hz 调制频
率的表指针增量值,请使用以下公式:
公式 3 :
f
/0.244 = 60/0.244
MOD
= 246 位
如果每次 PWM 中断时,将正弦表指针加上该值 246 ,那
么我们将会得到 60 Hz 的调制频率。
PWM
/216
对于此例,含有 256 个值的正弦表已经足够了。实际
上,此应用笔记提供的代码使用的是含有 64 个值的表,
而且能够提供良好的结果。
2005 Microchip Technology Inc. DS00984A_CN 第 5 页
AN984
如何产生带有相位偏移的多个正弦输出
我们想要产生具有不同相位的多个输出来驱动 ACIM 。
通过将指针变量加上固定的偏移值可以为某个特定的输
出确定相位偏移。
三相输出
二进制计数很适合在三相系统中使用。假定使用的指针
大小为 16 位,那么 0x5555 提供 120 度的偏移,而
0xAAAA 提供 240 度的偏移。 在每次 PWM 中断时将这
两个偏移值加上正弦表指针从而为第二和第三相提供两
个另外的指针。由于使用了 16 位运算,因此若正弦表
指针加上偏移后导致了溢出,将会使指针绕回到起始位
置。
单相输出
如果希望使用 H 桥逆变器驱动一相电机绕组,那么可以
用 0 度相位偏移调制桥的一边,用 180 度偏移调制桥的
另一边。如果使用 16 位正弦表指针,偏移值 0x8000 将
提供 180 度偏移。可能需要 90 度偏移来驱动分相电机
的副绕组。在这种情况下,可以使用正弦指针偏移值
0x4000 。
正弦表指针的获取
为了获得索引值以从表中查找正弦数据,将 16 位正弦指
针右移以丢弃在 “正弦表指针”部分中描述的 “小数”
位。如果使用含有 256 个值的表,则只需将指针的高 8
位用作查找表的索引。
正弦表中查找值的换算
一旦从表获得查找值之后,就会将这些值乘以比例值以
确定调制输出的实际幅值。“PWM 调制”部分提供了有
关换算的更多详情。
DS00984A_CN 第 6 页 2005 Microchip Technology Inc.
AN984
ACIM 转差与转矩
ACIM 必须有转差才能运行。转差是转子的机械速度与
由定子产生的旋转磁场的速度之差。转差可被表示为比
例或频率差。
为了说明转差,假定用 60 Hz 的交流输入电压为两极
ACIM 供电。如果转子跟随输入电压的频率同步旋转,
则转子将以 60 转每秒 (即 3600 RPM )的速度旋转。
然而由于转差,转子的转速略微低于同步速度
3600 RPM。通常在电机规格中注明转差。同步速度为
3600 RPM 的两极电机可能将 3450 RPM 指定为标称电
机速度。
图 7 : ACIM 转矩与转差关系曲线
T
起动转矩
制动区域
电动机
区域
下面的图 7 说明了电机转矩和转差之间的关系。当最初
为电机通电时,转子处于静止状态。在这一刻,转差为
最大值。此时电机将有一个有限的起动转矩。如果电机
负载没有超过起动转矩,电机将开始加速直到达到一个
接近同步速度的速度。然后电机将在转矩关系曲线 T 轴
右边的某个点工作。在此区域工作时,电机能够在有限
的范围之内对速度进行自我调节。当电机的转轴带有更
多负载时,电机速度自然会降低。速度的降低使转差增
加,从而使转矩增大。随着电机的负载越来越大,工作
点将向转矩曲线的左边移动直至达到失速转矩点。此时
转子停转。
失速转矩
工作点
同步速度
RPM
发电机
区域
1.5 1.0 0.5 0 -0.5 -1.0
转差
2005 Microchip Technology Inc. DS00984A_CN 第 7 页
AN984
压—频关系曲线
ACIM 通常设计成工作在固定的电压和频率下。在上一
节讨论的转矩曲线适用于一个频率。然而, ACIM 的自
我调节功能可被用来实现基本的变速控制。如果改变电
机的输入频率,电机的同步速度也将相应地变化。改变
频率可使转矩曲线左移或右移。如果连续调节电机的输
入频率,将产生一系列转矩曲线,如图 8 所示。由于电
机是感性负载,随着驱动频率的降低,电机的电抗也将
降低。因此,如果调节了驱动频率,那么也应该按比例
调节电压。对于变速 ACIM 而言,频率和电压之间的关
系称为压-频或 VF 曲线。
图 8 : 变频工作模式下的转矩曲线
转矩
5
0V/1
5
Hz
100V/30 Hz
Hz
5
V/4
50
1
0V/60 Hz
0
2
最经常使用的是电压和频率之间的线性关系。某个特定
电机所需的 VF 关系可通过电机铭牌上的参数确定。例
如,假定有一台设计为在 230 V 交流电压、60 Hz 频率
下工作的电机。如果想将电机驱动为工作在标称速度的
一半,则应使用一半大小的输入频率和输入电压。在此
例中,输入值大约为 115 V 和 30 Hz 。
实际上, VF 曲线可以是任意形状的。在某些工作频率
下可以提升驱动电压以在这些速度下提供更大的转矩。
例如,大多数 VF 曲线有一个低频提升区域以帮助电机
从零速起动。在此提升区域中,电压将被限制为最小
值。图 9 中所示为典型的 VF 曲线。
图 9 : VF 曲线示例
120
100
80
伏特 RMS
60
40
20
提升
区域
低频截止
20 40 60
频率 (Hz )
高幅值
固定 V/F
区域
极限
速度
DS00984A_CN 第 8 页 2005 Microchip Technology Inc.
AN984
软件操作
此应用笔记提供的源代码是一个非常基本的汇编代码示
例,使您能够开始着手进行 ACIM 的变速控制。
ADC 采样以及 VF 曲线计算
ADC 能够对 AN7 和 AN12 两路输入进行扫描,这两路
输入均与 dsPICDEM MC1 板上的电位计相连。每隔 16
个 PWM 周期由 PWM 模块触发一次 ADC 转换,并且在
两次采样 / 转换过程之后由 ADC 中断 CPU 。使用此配
置, ADC 能在 500 Hz 的频率下高效地采样 AN7 和
AN12 。在每次 ADC 中断时调用 ReadADC 子程序以读
取转换值并计算 VF 曲线上各点的值。
与 AN7 连接的电位计设置驱动频率。将 10 位 ADC 结
果右移两位,然后写入 Frequency 变量。频率分辨率
为 0.244 Hz/ 位,因此电位计最高可将驱动频率调节到
62 Hz 。
与 AN12 连接的电位计用来设置电压—频率比,它决定
VF 曲线的斜率。当电位计设置为满值时,VF 曲线的斜
率最大。将 AN7 和 AN12 的 ADC 结果左移以将它们转
换为小数值,从而简化数学运算。在小数运算中,
0x7FFF = 0.999 。使用小数 MPY 指令让这两个小数值相
乘。此次相乘的结果仍是一个小数值,该值可用来调节
调制电压,调节范围为 0 到 100% 。该乘积存储在
Amplitude 变量中。
Frequency 和 Amplitude 变量决定了产生正弦波的
输入参数。 Amplitude 的值是有限的,所以在运行
PWM 调制程序过程中将不会发生过调制。
在此应用中, ADC 和 VF 运算在 500 Hz 的频率下进行
以产生新的电压和频率值。应该注意的是,仅当需要改
变电机速度时,才需要进行 VF 运算。这将取决于具体
的应用。
PWM 调制
PWM 被配置为 16 KHz 的载波频率、互补输出和 2 µs
的死区时间。所需的死区时间长度取决于用来驱动电机
的功率电路。本笔记中的代码示例使用了具有 64 个值
的正弦波查找表来驱动电机。
每个 PWM 周期调用一次Modulation 子程序为电机三
相中的每一相计算占空比。此子程序在每次调用时均保
存所有的工作寄存器并在调用结束后恢复这些寄存器的
值,因此该子程序可在其他应用中使用。
首先函数装入正弦查找表指针以及与该调制程序相关的
各种变量和常数。正弦表被存储在程序存储器空间以节
省 RAM ,虽然在本例中节省 RAM 并不是考虑的重点。
将原来的调制角度 Phase 与Frequency 变量相加得到
经过调节的调制角度值。将 120 度的偏移值 0x5555 加
上经过调节的角度值得到第二相的调制角度,再加 120
度将获得第三相的调制角度。如果希望驱动单相电机,
可以修改这些偏移值。偏移值 0x4000 将提供 90 度的相
移。偏移值 0x8000 将提供 180 度的相移。
创建了三个调制角度之后,将它们右移以丢弃除高 6 位
之外的所有位。这样做的原因是正弦表仅有 64 个值,构
成一个指针值只需要 6 位。如果使用不同大小的正弦
表,那么将需要调节右移的位数。右移之后,将正弦表
指针左移一位以创建一个指向字节的指针。因为该表包
含的是字类型数值,所以需要将该指针值乘以 2 。
接下来的代码将重复三遍以得到每相的占空比。将三个
正弦表指针中的每一个与正弦表的程序存储器基地址相
加以构成实际的查找地址。使用读表指令从该表获得正
弦值。需要执行两次乘法和一次加法运算来计算每个占
空比。第一次乘法将正弦查找值换算为所需的调制幅
值。第二次乘法根据选定的 PWM 周期,将正弦查找值
换算到允许的 PWM 占空比值范围之内。 PWM 换算系
数是一个表示占空比为 50% 的值。该换算系数随后将与
此结果相加以提供 50% 的占空比偏移。
正弦查找表
使用电子表格计算正弦波数据表的值。表中的数据是 16
位有符号整型格式的,其中 0x7FFF 表示 +0.999 而
0x8000 表示 -1.0 。如果需要可以预先将该数据换算为最
大 PWM 占空比以免去Modulation 函数中的一步乘法
运算。
2005 Microchip Technology Inc. DS00984A_CN 第 9 页
AN984
系统设置
应用笔记的这一部分将说明如何将电机与 dsPICDEM 电
机控制开发系统相接。以下讨论假定您拥有本文档 “推
荐使用的硬件”部分列出的硬件。
dsPICDEM MC 板设置
需要连接演示板上的 VR1 。通过借用 CAN 或 RS-485
端口上 LK8 或LK9 上的跳线,将跳线置于仿真头 J6 上,
连接 VR1 与 AN12 。
如何将 3 相交流感应电机连接到电源模块
如果直接从分销商处订购电机,可能需要将电源线连接
到电机。将需要四根等长的 12-16 AWG 多股绞线和四
个导线连接器。导线长度最好保持在 3 英尺以下。大多
数三相 ACIM 可以接入两个不同的工作电压。在电机的
背面或一侧通常有一块板,移除它即可连线。
遵循电机面板上的接线图来为三个电源相和电机机座接
地端连接导线。遵循面板接线图使电机在 208V 工作。
把将要连接到电源模块的导线一端剥开并镀锡。
注意: 请始终保持电机机座接地以避免触电的危
险。
将三根电源线从电机连接到电源模块右边的 R 、 Y 和 B
端。除非需要特定的旋转方向,电源线连接到哪个电源
端没有关系。确保将电机机座的地线连接到电源模块右
侧的接地端。
如何将分相交流感应电机连接到电源模块
分相 ACIM 具有主绕组和副绕组。小型的分相 ACIM 通
常已经安装了电源线。分相 ACIM 通常有三根电源线:
一根为主绕组通电、一根为副绕组通电,还有一根公共
线与两个绕组的另一端相连。
可以使用欧姆计确定每根电源线的功能。副绕组比主绕
组的阻抗大得多。当欧姆计跨接在主绕组和副绕组之间
时,可以测量两个绕组阻抗和。
一旦确定了每根线的功能,就请为它们贴上 “主” 、
“副”和 “公共”的标签。分相电机被设计为通过电容
与副绕组串联的方式驱动,如图 5 所示。电容为副绕组
电流加入了一个相移,因而可通过单相电压源建立旋转
磁通。电容规格由电机制造商提供。若使用了电容,就
可将电机连接到电源模块,如图 5 所示。如果需要,分
相电机也可以在没有副绕组电容的情况下由电源模块驱
动。此配置的连接详情如图 4 所示。
DS00984A_CN 第 10 页 2005 Microchip Technology Inc.
AN984
连接步骤
1. 将交流电源线连接到电源模块左侧的端子。需要
一根一端有交流电源插头而另一端剥开的线缆。
按以下方式连接。确保连接可靠。
- 将绿线 (地线)连接到接地端
- 将白线连接到 N (零线)端
- 将黑线连接到 L (相线)端
注意: 您可能有一根带有绿线、蓝线和棕线的交
流电源线。如果是这样,将绿线连接到接
地端、蓝线连接到 N 端、棕线连接到 L 端。
2. 将 dsPICDEM MC1 演示板插入电源模块。该板
和电源模块使用 37 引脚的 D 型连接器相连。在
该板和电源模块之间不应该使用任何线缆。
3. 为演示板加上 9 V 的直流电源。
4. 现在,为 HV 电源模块插上交流电源线。通过电
源模块顶部的通风孔朝里看, 在 PCB 的右侧靠
近输出端的地方,有一个红色的 LED ,表明直流
母线上是否有高压。如果需要改变与该模块的连
接,请断开电源并等待此 LED 熄灭。
5. 编译应用笔记源代码文件 acim_vhz.s ,并对
dsPIC 器件进行编程。可以使用 MPLAB ICD 2
在线调试器对该器件编程。将 ICD 2 通信线缆连
接到 dsPICDEM MC1 板左侧的连接器 J4 。确 保
在器件编程期间,板上的开关 S2 是置于“ICD ”
位置的。
6. 在运行源代码前,确保将 VR1 和 VR2 调节为最
小设置。
输入电压的注意事项
在不同的地区,交流电源的电压也可能不同。该电源模
块可用最高为 230 V 的交流电源供电。在有些情况下,
交流电源的电压可能会与电机的工作电压不匹配。很多
三相 ACIM 被设计为在 208 到 230 V 交流输入下工作。
您可能只有 120 V 的交流电源。在这种情况下,电机仍
能正常工作,但是转矩输出有限制。这一点不会对后续
部分介绍的实验产生任何影响,而仅仅意味着对于给定
的驱动频率,驱动电压将为所需值的一半。
解决电压不匹配的一个方法是根据现有的电压限制驱动
频率的范围。可以将 ReadADC 子程序中计算的
Frequency 变量除以 2,这样做可以将频率范围限制在
31 Hz 以内,从而将电机速度范围缩小一半。在此速度
范围内,电机将产生其对应大小的转矩。
2005 Microchip Technology Inc. DS00984A_CN 第 11 页
AN984
试验
此部分介绍了一些可采用的试验。这些试验将帮助您很
好地理解在变速应用中 ACIM 如何响应不同的电压和频
率。
试验 1
在此试验中,您将观察电机对速度变化的响应 (电机速
度随 VF 曲线斜率变化)。
1. 调节 VR1 至 25% 与 50% 之间,将 VF 曲线斜率
设置为相对较低的值。
2. 尝试使用 VR2 改变电机的速度。您可能会注意到
电机速度的改变比较缓慢。
3. 现在,尝试更改 VR1 的值,从而改变电机的速
度。您应该发现当 VF 曲线斜率增大时,电机速
度的变化要快得多。
如果 VR1 设置得太高,就可能会发生过电流的情况。电
源模块上的红色 LED 将被点亮。如果出现过电流跳变,
可通过复位软件清除这种情况。在起动时对 RE9 引脚施
加脉冲为电源模块提供错误复位信号。
试验 2
在此试验中,您将观察当频率保持恒定而改变幅值时,
电机转矩如何改变。
1. 通过将 VR2 设置为一个很低的值 (低于 25% )
来起动电机。这样做会将调制频率设置为相对较
低的值,以低速运行电机。
2. 开始时将 VR1 设置为零,然后缓慢地增大设置
值,同时用手握住电机转轴使之停止不动。 应该
感觉到电机的转矩随着 VR1 的增大而增大。
在这种情况下,电机工作于可变转矩模式。当幅值改变
时,保持频率恒定。
结论
此应用笔记给出了一个简单的代码示例,您可以用它来
实现 ACIM 的变速控制。有关 ACIM 高级应用的详细信
息,请参阅 AN908
机的矢量控制》
,《使用
(DS00908A_CN )。
dsPIC30F
实现交流感应电
DS00984A_CN 第 12 页 2005 Microchip Technology Inc.
AN984
源代码清单
软件许可协议
Microchip Technology Incorporated (“公司”)随附提供的软件旨在提供给您 (该公司的客户)使用,且仅限于在该公司制造的产
品上使用。
该软件为公司和 / 或其供应商所有,并受适用的版权法保护。版权所有。任何违反前述限制的使用将使其受到适用法律的刑事制裁,
并且承担违背此许可条款和条件的民事责任。
该软件 “按现状”提供。不提供保证,无论是明示的、暗示的还是法定的保证。这些保证包括 (但不限于)对出于某一特定目的应
用此软件的适销性和适用性默示的保证。在任何情况下,公司都将不会对任何原因造成的特别的、偶然的或间接的损害负责。
;******************************************************************************
; *
; 文件名 : acim_vhz.s
; *
;******************************************************************************
; 注: *
; ====== *
; A/D 用以对 dsPICDEM-MC1 演示板上两个与 AN7 和 AN12 连接的电位计进行采样。
; VR1 用来改变调制的 V/Hz 比值。 VR2 用来改变调制频率。 通过用两个电位计进行试验,
; 可以找到一个最佳的 V/Hz 比值来驱动电机。
; *
; *
;******************************************************************************
.equ __30F6010, 1
.include "C:\pic30_tools\support\inc\p30f6010.inc"
.global__reset
;..............................................................................
; 配置位:
;..............................................................................
config __FOSC, CSW_FSCM_OFF & XT_PLL4 ; 关闭时钟切换和
; 故障保护时钟监视并
; 使用 XT 振荡器和 4 倍频 PLL 作为
; 系统时钟
config __FWDT, WDT_OFF ; 关闭看门狗定时器
config __FBORPOR, PBOR_ON & BORV_27 & PWRT_16 & MCLR_EN
; 设置欠压复位电压
config __FGS, CODE_PROT_OFF ; 对一般代码段
;..............................................................................
; 近数据存储器 ( RAM 的低 8KB)中的未初始化变量
;..............................................................................
; 并将上电延迟定时器设置为 16ms
; 将代码保护设置为关闭
.section .nbss, "b"
; 在每个 PWM 周期将此变量加到 16 位的
; 正弦波数值表指针。对于 16 KHz 的 PWM 调制,数值 246 将提供
Frequency:.space 2
2005 Microchip Technology Inc. DS00984A_CN 第 13 页
;60 Hz 的调制频率
; 此变量用来设置调制幅值并换算
; 从正弦波数值表获取的值。有效值的范围为 0 到 32767
AN984
Amplitude:.space 2
; 此变量是正弦波数值表的指针。在每次 PWM 中断时,
Phase: .space 2
;..............................................................................
; 存储在程序空间中的常数
;..............................................................................
SineTable:
.hword 0,3212,6393,9512,12539,15446,18204,20787,23170,25329
.hword 27245,28898,30273,31356,32137,32609,32767,32609,32137,31356,30273,28898
.hword 27245,25329,23170,20787,18204,15446,12539,9512,6393,3212,0,-3212,-6393
.hword -9512,-12539,-15446,-18204,-20787,-23170,-25329,-27245,-28898,-30273
.hword -31356,-32137,-32609,-32767,-32609,-32137,-31356,-30273,-28898,-27245
.hword -25329,-23170,-20787,-18204,-15446,-12539,-9512,-6393,-3212
;..............................................................................
; 此应用程序中的常数
;..............................................................................
; 它递增一次,递增数值是 Frequency 变量的值。
.section .sine_table, "x"
.align256
; 这是一个含有 64 个值的正弦波表,覆盖了正弦函数的 360 度。
; 使用 Microsoft Excel 计算这些值并将它们粘贴到此程序中。
; 此常量用来将正弦查找值换算到 PWM 占空比的有效范围内。占空比的范围取决于写入 PTPER 的值。
; 对于此应用程序,我们将设置 PTPER = 230,使占空比介于 0 和 460 之间。正弦表数据是有符号的,
; 我们用 230 乘以表中数据,然后将乘积加上固定的偏移值从而将查找数据换算为正值
.equ PWM_Scaling, 230
; 正弦波表的指针是 16 位的。把 0x5555 加给
; 指针将提供 120 度的偏移,而加上 0xAAAA 将提供 240
; 度的偏移。这些偏移用来获取 PWM 输出的相位 2 和相位 3 的查找值。
.equ Offset_120, 0x5555
;..............................................................................
; 程序存储器中的代码部分
;..............................................................................
.text ; 代码部分的开始
__reset:
MOV #__SP_init, W15 ; 初始化堆栈指针
MOV #__SPLIM_init, W0 ; 初始化堆栈指针限制寄存器
MOV W0, SPLIM
;-----------------------------------------------------------------------------; 初始化变量
;------------------------------------------------------------------------------
NOP ; 在初始化 SPLIM 之后,加一条 NOP
CALL _wreg_init ; 调用 _wreg_init 子程序
; 可以选用 RCALL 代替 CALL
call Setup ; 调用程序以设置 I/O 和 PWM
clr Frequency
clr Amplitude
DS00984A_CN 第 14 页 2005 Microchip Technology Inc.
AN984
;-----------------------------------------------------------------------------; 主循环代码
; 在主循环中查询 PWM 中断标志
;------------------------------------------------------------------------------
Loop: btss IFS2,#PWMIF ; 查询 PWM 中断标志
bra CheckADC ; 如果置 1,则继续
call Modulation ; 调用正弦波调制程序
bclr IFS2, #PWMIF ; 清零 PWM 中断标志
CheckADC:
btss IFS0,#ADIF
bra Loop
call ReadADC
bra Loop
;-----------------------------------------------------------------------------; ADC 处理子程序
;-----------------------------------------------------------------------------ReadADC:
push.d W0
push.d W4
mov ADCBUF0,W0 ; 将 ADC 结果读入 W0
mov ADCBUF1,W1 ; 和 W1。
asr W0,#2,W4 ; 右移 2 位以得到
mov W4,Frequency ; 调制频率。
sl W1,#5,W4 ; 将 AN7 和 AN12 的值左移以得到
sl W0,#5,W5 ; 1.15 格式的小数数据。
mpy W4*W5,A ; 将频率与 V/Hz 的商相乘得到
sac A,W0 ; 调制幅值。将结果存储在 W0 中。
mov #28000,W1 ; 限制调制幅值以避免
cp W1,W0 ; 在 PWM 调制中由死区引起的
bra GE,NoLimit ; 失真。
mov W1,W0
NoLimit:
mov W0,Amplitude
pop.d W4
pop.d W0
return
;------------------------------------------------------------------------------
; PWM 正弦波调制子程序
;------------------------------------------------------------------------------
Modulation:
push.d W0 ; 保存工作寄存器
push.d W2
push.d W4
push.d W6
push.d W8
push.d W10
; 下面的三条指令初始化 TBLPAG 和指针寄存器
; 从而可使用读表操作来访问程序存储器中的正弦波数据。
mov #tblpage(SineTable),W0
mov W0,TBLPAG
2005 Microchip Technology Inc. DS00984A_CN 第 15 页
AN984
mov #tbloffset(SineTable),W0
; 下面的指令块装载正弦波调制程序中使用的各种常数和变量。
mov Phase,W1 ; 装载正弦波表指针
mov #Offset_120,W4 ; 这是 120 度偏移的值
mov Amplitude,W6 ; 装载幅值换算系数
mov #PWM_Scaling,W7 ; 装载 PWM 换算值
mov Frequency,W8 ; 装载将在每次中断时与表指针相加的 Frequency 常数。
; 这是指针调节代码。将 Frequency 值加给正弦表指针以使指针在正弦表中前移。
; 然后,为此指针加上相应的偏移值以得到相位 2 和相位 3 的指针。
; 注意:如果需要不同的相位偏移,可以在这里使用其他常数值。
; 加上 0x4000 将得到 90 度偏移,加上 0x8000 将
; 提供 180 度偏移。 在此将 0x5555 装入 W4 以提供 120 度偏移。
add W8,W1,W1 ; 将 Frequency 值加给正弦指针
add W1,W4,W2 ; 加上 120 度偏移值以得到相位 2 的指针
add W2,W4,W3 ; 再加上 120 度偏移以得到相位 3 的指针
; 该正弦表有 64 个值,所以将指针右移
; 以得到一个 6 位的指针值。
lsr W1,#10,W9 ; 将相位 1 的指针右移以得到高 6 位
sl W9,#1,W9 ; 左移一位转换为字节地址
lsr W2,#10,W10 ; 将相位 2 的指针右移以得到高 6 位
sl W10,#1,W10 ; 左移一位转换为字节地址
lsr W3,#10,W11 ; 将相位 3 的指针右移以得到高 6 位
sl W11,#1,W11 ; 左移一位转换为字节地址
; 现在,将每个相位的指针与基表指针相加以获得查找值的绝对表地址。
; 然后将查找值换算为正确的幅值和在有效的占空比范围之内。
; 下面的指令块为相位 1 计算占空比。为相位 2 和相位 3 计算占空比的代码与此相同。
add W0,W9,W9 ; 形成相位 1 的表地址
tblrdl [W9],W5 ; 读相位 1 的查找值
mpy W5*W6,A ; 乘以幅值换算系数
sac A,W5 ; 存储经过换算的结果
mpy W5*W7,A ; 乘以 PWM 换算系数
sac A,W8 ; 存储经过换算的结果
add W7,W8,W8 ; 加上 PWM 换算系数以产生 50% 的偏移
mov W8,PDC1 ; 写 PWM 占空比
; 下面的代码块为相位 2 计算占空比。
add W0,W10,W10 ; 形成相位 2 的表地址
tblrdl [W10],W5 ; 读相位 2 的查找值
mpy W5*W6,A ; 乘以幅值换算系数
sac A,W5 ; 存储经过换算的结果
mpy W5*W7,A ; 乘以 PWM 换算系数
sac A,W8 ; 存储经过换算的结果
add W7,W8,W8 ; 加上 PWM 换算系数以产生 50% 的偏移
mov W8,PDC2 ; 写 PWM 占空比
; 下面的代码块为相位 3 计算占空比。
add W0,W11,W11 ; 形成相位 3 的表地址
tblrdl [W11],W5 ; 读相位 3 的查找值
DS00984A_CN 第 16 页 2005 Microchip Technology Inc.
AN984
mpy W5*W6,A ; 乘以幅值换算系数
sac A,W5 ; 存储经过换算的结果
mpy W5*W7,A ; 乘以 PWM 换算系数
sac A,W8 ; 存储经过换算的结果
add W7,W8,W8 ; 加上 PWM 换算系数以产生 50% 的偏移
mov W8,PDC3 ; 写 PWM 占空比
; 现在,保存经过调节的正弦波表指针从而能
; 在此代码的下一次迭代中使用它。
mov W1,Phase
pop.d W10 ; 恢复工作寄存器
pop.d W8
pop.d W6
pop.d W4
pop.d W2
pop.d W0
return ; 从子程序返回
;-----------------------------------------------------------------------------; PWM 和 ADC 的设置代码
;-------------------------------------------------------------------------------------
Setup:
; 在使能 PWM 之前需要做的第一件事是配置 I/O 并复位电源模块。
; 该控制板有一个缓冲 PWM 控制线的驱动器 IC。
; RD11 端口上的有效低电平使能该缓冲器。
; 此电源模块有一条与端口 RE9 相连的高电平有效复位线路。
clr PORTD
clr PORTE
mov #0xF7FF,W0 ; 设置 RD11 输出驱动 PWM 缓冲器
mov W0,TRISD ; 使能。
mov #0xFDFF,W0;
mov W0,TRISE ; 设置 RE9 输出复位电源模块
; 现在,通过驱动复位线并保持几个微秒来确保电源模块复位。
bset PORTE,#9
repeat #39
nop
bclr PORTE,#9
; 设置 ADC
mov #0x0404,W0 ; 扫描输入
mov W0,ADCON2 ; 每次中断进行 2 次采样 / 转换
mov #0x0003,W0;
mov W0,ADCON3 ; Tad 是 2 个 Tcy
clr ADCHS ;
clr ADPCFG ; 将所有 A/D 引脚设置为模拟模式
clr ADCSSL ;
bset ADCSSL,#7 ; 使能对 AN7 的扫描
bset ADCSSL,#12 ; 使能对 AN12 的扫描
mov #0x8066,W0 ; 使能 A/D、 PWM 触发和自动采样
mov W0,ADCON1 ;
bclr IFS0,#ADIF ; 清零 A/D 中断标志位
2005 Microchip Technology Inc. DS00984A_CN 第 17 页
AN984
; 现在设置 PWM 寄存器
mov #0x0077,W0 ; 互补模式,使能 #1、 #2 和 #3
mov W0,PWMCON1 ; 三对 PWM 输出
mov #0x000F,W0 ; 器件运行速度为 7.38 MIPS 时,将产生 2μs 的死区
mov W0,DTCON1
mov #PWM_Scaling, W0 ; 器件运行速度为 7.38 MIPS 时,为 16KHz PWM 设置周期
mov W0,PTPER
mov #0x0001,W0 ;
mov W0,SEVTCMP ; 将 ADC 设置为以特殊事件触发启动
mov #0x0F00,W0 ; 将特殊事件后分频比设置为 1:16
mov W0,PWMCON2 ;
mov #0x8002,W0 ; 使能 PWM 时基,中心对齐模式
mov W0,PTCON
return ; 从 Setup 子程序返回
;..............................................................................
; 子程序:将 W 寄存器初始化为 0x0000
;..............................................................................
_wreg_init:
CLR W0
MOV W0, W14
REPEAT #12
MOV W0, [++W14]
CLR W14
RETURN
;-------- 所有代码部分结束 ---------------------------------------------
.end ; 此文件中程序代码的结尾
DS00984A_CN 第 18 页 2005 Microchip Technology Inc.
请注意以下有关 Microchip 器件代码保护功能的要点:
•M i c r o c h i p的产品均达到 Microchip 数据手册中所述的技术指标。
•M i c r o c h i p确信:在正常使用的情况下, Microchip 系列产品是当今市场上同类产品中最安全的产品之一。
• 目前,仍存在着恶意、甚至是非法破坏代码保护功能的行为。就我们所知,所有这些行为都不是以 Microchip 数据手册中规定的操
作规范来使用 Microchip 产品的。这样做的人极可能侵犯了知识产权。
•M i c r o c h i p愿与那些注重代码完整性的客户合作。
•M i c r o c h i p或任何其他半导体厂商均无法保证其代码的安全性。代码保护并不意味着我们保证产品是 “牢不可破”的。
代码保护功能处于持续发展中。 Microchip 承诺将不断改进产品的代码保护功能。任何试图破坏 Microchip 代码保护功能的行为均可视
为违反了《数字器件千年版权法案 (Digital Millennium Copyright Act )》。如果这种行为导致他人在未经授权的情况下,能访问您的软
件或其他受版权保护的成果,您有权依据该法案提起诉讼,从而制止这种行为。
提供本文档的中文版本仅为了便于理解。Microchip
Technology Inc. 及其分公司和相关公司、各级主管与员工及
事务代理机构对译文中可能存在的任何差错不承担任何责任。
建议参考 Microchip Technology Inc. 的英文原版文档。
本出版物中所述的器件应用信息及其他类似内容仅为您提供便
利,它们可能由更新之信息所替代。确保应用符合技术规范,
是您自身应负的责任。Microchip 对这些信息不作任何明示或
暗示、书面或口头、法定或其他形式的声明或担保,包括但不
限于针对其使用情况、质量、性能、适销性或特定用途的适用
性的声明或担保。 Microchip 对因这些信息及使用这些信息而
引起的后果不承担任何责任。未经 Microchip 书面批准,不得
将 Microchip 的产品用作生命维持系统中的关键组件。在
Microchip 知识产权保护下,不得暗中或以其他方式转让任何
许可证。
商标
Microchip 的名称和徽标组合、 Microchip 徽标、 Accuron、
dsPIC、 K
EEL OQ、 microID 、 MPLAB、 PIC、 PICmicro、
PICSTART、 PRO MATE、 PowerSmart、 rfPIC 和
SmartShunt 均为 Microchip Technology Inc. 在美国和其他国
家或地区的注册商标。
AmpLab、 FilterLab、 Migratable Memory、 MXDEV、
MXLAB、 PICMASTER、 SEEVAL、 SmartSensor 和 The
Embedded Control Solutions Company 均为 Microchip
Technology Inc. 在美国的注册商标。
Analog-for-the-Digital Age、 Application Maestro、
dsPICDEM、 dsPICDEM.net、 dsPICworks、 ECAN、
ECONOMONITOR、 FanSense、 FlexROM、 fuzzyLAB、
In-Circuit Serial Programming、 ICSP、 ICEPIC、 Linear
Active Thermistor、 MPASM、 MPLIB、 MPLINK、 MPSIM、
PICkit、 PICDEM、 PICDEM.net、 PICLAB、 PICtail、
PowerCal、 PowerInfo、 PowerMate、 PowerTool、 rfLAB、
rfPICDEM、 Select Mode、 Smart Serial、 SmartTel、 To ta l
Endurance 和 WiperLock 均为 Microchip Technology Inc.在
美国和其他国家或地区的商标。
SQTP 是 Microchip Technology Inc. 在美国的服务标记。
在此提及的所有其他商标均为各持有公司所有。
© 2005, Microchip Technology Inc . 版权所有。
Microchip
州
月通过了
单片机、
存储器和模拟产品方面的质量体系流程均符合
此外,
ISO 9001:2000
位于美国亚利桑那州
Mountain View
ISO/TS-16949:2002
KEE LOQ
Microchip
的全球总部、设计中心和晶圆生产厂均于
®
跳码器件、串行
在开发系统的设计和生产方面的质量体系也已通过了
认证。
Chandler和Tem pe
质量体系认证。公司在
EEPROM
及位于加利福尼亚
2003年10
®
PICmicro
、单片机外设、非易失性
ISO/TS-16949:2002
8
位
。
2005 Microchip Technology Inc. DS00984A_CN 第 19 页
全球销售及服务网点
美洲
公司总部 Corporate Office
2355 West Chandler Blvd.
Chandler, AZ 85224-6199
Tel: 1-480-792-7200
Fax: 1-480-792-7277
技术支持:
http://support.microchip.com
网址:www.microchip.com
亚特兰大 Atlanta
Alpharetta, GA
Tel: 1-770-640-0034
Fax: 1-770-640-0307
波士顿 Boston
Westborough, MA
Tel: 1-774-760-0087
Fax: 1-774-760-0088
芝加哥 Chicago
Itasca, IL
Tel: 1-630-285-0071
Fax: 1-630-285-0075
达拉斯 Dallas
Addison, TX
Tel: 1-972-818-7423
Fax: 1-972-818-2924
底特律 Detroit
Farmington Hills, MI
Tel: 1-248-538-2250
Fax: 1-248-538-2260
科科莫 Kokomo
Kokomo, IN
Tel: 1-765-864-8360
Fax: 1-765-864-8387
洛杉矶 Los Angeles
Mission Viejo, CA
Tel: 1-949-462-9523
Fax: 1-949-462-9608
圣何塞 San Jose
Mountain View, CA
Tel: 1-650-215-1444
Fax: 1-650-961-0286
加拿大多伦多 Tor ont o
Mississauga, Ontario,
Canada
Tel: 1-905-673-0699
Fax: 1-905-673-6509
亚太地区
中国 - 北京
Tel: 86-10-8528-2100
Fax: 86-10-8528-2104
中国 - 成都
Tel: 86-28-8676-6200
Fax: 86-28-8676-6599
中国 - 福州
Tel: 86-591-8750-3506
Fax: 86-591-8750-3521
中国 - 香港特别行政区
Tel: 852-2401-1200
Fax: 852-2401-3431
中国 - 上海
Tel: 86-21-5407-5533
Fax: 86-21-5407-5066
中国 - 沈阳
Tel: 86-24-2334-2829
Fax: 86-24-2334-2393
中国 - 深圳
Tel: 86-755-8203-2660
Fax: 86-755-8203-1760
中国 - 顺德
Tel: 86-757-2839-5507
Fax: 86-757-2839-5571
中国 - 青岛
Tel: 86-532-8502-7355
Fax: 86-532-8502-7205
中国 - 武汉
Tel: 86-27-5980-5330
Fax: 86-27-5980-5118
台湾地区 - 高雄
Tel: 886-7-536-4818
Fax: 886-7-536-4803
台湾地区 - 台北
Tel: 886-2-2500-6610
Fax: 886-2-2508-0102
台湾地区 - 新竹
Tel: 886-3-572-9526
Fax: 886-3-572-6459
亚太地区
澳大利亚 Australia - Sydney
Tel: 61-2-9868-6733
Fax: 61-2-9868-6755
印度 India - Bangalore
Tel: 91-80-2229-0061
Fax: 91-80-2229-0062
印度 India - New Delhi
Tel: 91-11-5160-8631
Fax: 91-11-5160-8632
日本 Japan - Kanagawa
Tel: 81-45-471- 6166
Fax: 81-45-471-6122
韩国 Korea - Seoul
Tel: 82-2-554-7200
Fax: 82-2-558-5932 或
82-2-558-5934
马来西亚 Malaysia - Penang
Tel:011-604-646-8870
Fax:011-604-646-5086
菲律宾 Philippines - Manila
Tel: 011-632-634-9065
Fax: 011-632-634-9069
新加坡 Singapore
Tel: 65-6334-8870
Fax: 65-6334-8850
欧洲
奥地利 Austria - Weis
Tel: 43-7242-2244-399
Fax: 43-7242-2244-393
丹麦 Denmark - Ballerup
Tel: 45-4450-2828
Fax: 45-4485-2829
法国 France - Massy
Tel: 33-1-69-53-63-20
Fax: 33-1-69-30-90-79
德国 Germany - Ismaning
Tel: 49-89-627-144-0
Fax: 49-89-627-144-44
意大利 Italy - Milan
Tel: 39-0331-742611
Fax: 39-0331-466781
荷兰 Netherlands - Drunen
Tel: 31-416-690399
Fax: 31-416-690340
英国 England - Berkshire
Tel: 44-118-921-5869
Fax: 44-118-921-5820
06/08/05
DS00984A_CN 第 20 页 2005 Microchip Technology Inc.